Apuração de Horas Extras – parte 2

Dando continuidade ao post anterior (Apuração de horas extras com o auxílio do Excel), irei incrementar a planilha Controle de ponto v.1 com o cálculo em separado das horas laboradas em domingos e feriados.

O primeiro passo é inserir na planilha uma tabela contendo os feriados nacionais, municipais e, quando existente, o feriado estadual.

De acordo com a Lei 9.093/1995, os feriados a serem observados pelos empregadores são os seguintes:

a) civis e nacionais (fixados em lei federal);
b) 04 (quatro) feriados religiosos declarados em lei municipal, um dos quais há de ser necessariamente a Sexta-feira da Paixão;
c) a partir de 13.09.1995, um feriado civil relativo à data magna do Estado fixada em lei estadual;
d) os dias do início e do término do ano do centenário de fundação do Município, fixados em lei municipal. (Inciso acrescido pela Lei nº 9.335, de 10/12/1996)

Os feriados nacionais são:

• 01 de janeiro (Confraternização Universal) – art. 1º da Lei 662, de 06/05/1949;
• 21 de abril (Tiradentes) – art. 1º da Lei 662, de 06/05/1949;
• 01 de maio (Dia do Trabalho) – art. 1º da Lei 662, de 06/05/1949;
• 07 de setembro (Independência) – art. 1º da Lei 662, de 06/05/1949;
• 12 de outubro (Padroeira do Brasil) – Lei nº 6.802, de 30/06/1980;
• 02 de novembro (Finados) – art. 1º da Lei 662, de 06/05/1949;
• 15 de novembro (Proclamação da República) – art. 1º da Lei 662, de 06/05/1949;
• 25 de dezembro (Natal) – art. 1º da Lei 662, de 06/05/1949.

info O dia de Finados (02 de novembro) passou a ser considerado feriado nacional a partir de 19/12/2002, em virtude da Lei nº 10.607/2001, que deu nova redação ao artigo 1º da Lei nº 662/1949.

Feriados Fixos e Móveis

No Excel, para elaborarmos uma tabela de feriados temos que considerar que há feriados fixos e móveis.

Feriados fixos – são os que ocorrem em uma data específica do ano como, por exemplo, todos os feriados nacionais: 01 de janeiro, 21 de abril, 01 de maio, 07 de setembro, 12 de outubro, 02 de novembro, 15 de dezembro, e 25 de dezembro. Ao todo, 8 feriados.

Feriados móveis – no Brasil, os feriados móveis que conheço são religiosos e ocorrem em datas relacionadas com a Páscoa.

Por exemplo, para calcularmos em que data irá cair o feriado da Sexta-feira da Paixão do ano de 2020, temos que, primeiro, calcular em que domingo irá cair a Páscoa do ano de 2020.

Ao contrário dos Estados Unidos, não temos no Brasil feriados móveis que ocorrem no n-ésimo dia da semana de um mês, como, por exemplo, o dia de Martin Luther King que cai na terceira segunda-feira de Janeiro.

A partir do domingo de Páscoa é possível calcular os feriados móveis, tais como Sexta-feira da Paixão, Corpus Christi e Carnaval:

• Terça-feira de carnaval – 47 dias antes da Páscoa;
• Sexta-feira da Paixão – 2 dias antes da Páscoa;
• Corpus Christi – 60 dias depois da Páscoa (sempre cai em uma quinta-feira)

info Atenção: Corpus Christi e Terça-feira de Carnaval não são feriados nacionais. Assim, somente se a legislação municipal ou estadual incluir esses dias entre os feriados é que essas datas poderão ser consideradas como feriados.

Em Foz do Iguaçu, por exemplo, Corpus Christi é feriado municipal e Terça-feira de Carnaval não é. Quanto ao Estado do Rio de Janeiro, a lei n° 5.243/2008 instituiu a Terça-feira de Carnaval como feriado estadual.

Depois destas considerações iniciais a respeito dos feriados, vamos à prática, tomando como ponto de partida a planilha Controle de ponto v.1 disponibilizada no primeiro post.

Inserindo os feriados fixos:

01 – Em R8 vamos inserir o feriado do ano novo e, em S8, o nome do feriado. Para que a tabela de feriados possa ser alterada automaticamente sempre que mudar o ano, temos que inserir uma fórmula ao invés de simplesmente digitar 01/01/2015. A fórmula em R8 é:

=DATA($C$2;1;1)

02 – Com o recurso da função DATA, fixamos apenas o dia 01 e o mês 01. O ano corresponderá ao valor digitado em C2, automatizando o cálculo para qualquer ano, posterior ou anterior.

03 – Nas células abaixo vamos inserir os demais feriados fixos:

• Em R9 =DATA($C$2;04;21), em S9 – Tiradentes;
• Em R10 =DATA($C$2;05;01), em S10 – Dia do Trabalho;
• Em R11 =DATA($C$2;09;07), em S11 – Independência;
• Em R12 =DATA($C$2;10;12), em S12 – Padroeira do Brasil;
• Em R13 =DATA($C$2;11;02), em S13 – Finados;
• Em R14 =DATA($C$2;11;15), em S14 – Proclamação da República;
• Em R15 =DATA($C$2;12;25), em S15 – Natal.

04 – Depois de inserir os feriados fixos nacionais, temos que inserir os feriados fixos municipais e também o estadual, caso existente.

05 – Em se tratando de feriados fixos, a fórmula básica é a mesma:

=DATA(ano;mês;dia)

06 – Cada usuário terá que adaptar a fórmula de acordo com os feriados do seu município. Foz do Iguaçu, por exemplo, conta com dois feriados fixos: 10 de junho (aniversário do município) e 24 de junho (padroeiro da cidade). Então:

• Em R16 =DATA($C$2;06;10), em S16 – Aniversário do Município;
• Em R17 =DATA($C$2;06;24), em S17 – Padroeiro da Cidade.

07 – Depois de inseridos todos os feriados fixos, vamos agora preencher a tabela com os feriados móveis.

08 – Como explicado acima, para conhecermos a data dos feriados móveis, temos que calcular a Páscoa.

09 – Há, na literatura especializada sobre Excel, várias fórmulas para cálculo da Páscoa. A que utilizaremos nesta planilha é:

=ARRED(DATA($C$2;4;MOD(234-11*MOD($C$2;19);30))/7;)*7-6

10 – A fórmula acima deverá ser inserida em alguma célula fora da tabela de feriados, por exemplo, em P8, pois o domingo de Páscoa não é feriado.

11 – Considerando que o ano em C2 é 2015, a fórmula acima retornará a data de 05/04/2015.

12 – Para facilitar o cálculo dos feriados móveis vamos usar um recurso do Excel que é nomear a célula P8.

13 – No Excel 2013, selecione a célula P8, clique na guia Fórmulas na interface do usuário e, em seguida, no grupo Nomes Definidos, clique em Definir Nomes para exibir a caixa de diálogo Novo Nome. Na caixa de diálogo Novo Nome, digite páscoa no campo Nome e verifique se a célula selecionada (no nosso exemplo a P8) aparece no campo Refere-se a e clique em OK. Se tudo foi feito corretamente, quando você selecionar a célula P8 irá aparecer o nome páscoa na Caixa de nome, conforme demonstrado na imagem abaixo:

pascoa

14 – Apenas para efeitos exemplificativos, vamos considerar que, além da Sexta-feira Santa, os feriados móveis municipais são Corpus Christi e Terça-feira de Carnaval.

15 – A fórmula para cálculo da Sexta-feira Santa a ser inserida em R18 será:

=páscoa-2

16 – Fórmula de Corpus Christi a ser inserida em R19:

=páscoa+60

17 – Fórmula da Terça-feira de Carnaval a ser inserida em R20:

=páscoa-47

info 18 – Lembrando, mais uma vez, que Terça-feira de Carnaval não é considerado feriado na maior parte dos municípios brasileiros.

fórmulas

19 – Para facilitar os cálculos posteriores, vamos nomear a tabela Feriados da mesma forma que nomeamos a célula P8.

20 – Selecione o intervalo R8 a R20, clique na guia Fórmulas na interface do usuário (Excel 2007 ou superior) e, em seguida, no grupo Nomes Definidos, clique em Definir Nomes para exibir a caixa de diálogo Novo Nome. Na caixa de diálogo Novo Nome, digite fer no campo Nome. Verifique se as células selecionadas (R8 a R20) aparecem no campo Refere-se a e clique em OK. Se tudo foi feito corretamente, a tabela de feriados está nomeada com o nome fer, que será o nome utilizado nas fórmulas das colunas C e I.

21 – Por último, falta introduzir um rótulo na tabela de feriados. Mescle e centralize o intervalo R7:S7 e digite a fórmula:

=”FERIADOS”&” “&$C$2

22 – Considerando que o valor do ano em C2 é 2015, a fórmula acima retornará FERIADOS 2015. Pronto, nossa tabela de feriados está finalizada.

tabela

23 – Agora temos que modificar as fórmulas de cálculo das horas normais e horas extras. A ideia desta versão é que, se o trabalhador laborou em domingos e feriados, sem folga compensatória, todas as horas trabalhadas nestes dias devem ser registradas como horas extras em uma coluna específica (no nosso exemplo, será a coluna K).

24 – Vamos começar modificando a fórmula da coluna C. Para que o Excel reconheça quando a data na coluna B é parte de uma tabela de datas de feriados, a fórmula em C8 deverá ser modificada para:

=SE(B8=””;””;SE(CONT.SE(fer;B8)>0;”feriado”;B8))

25- Se a função CONT.SE(fer;B8)>0 retornar VERDADEIRO, a data em B8 é um feriado.

26 – A fórmula da Coluna H permanece a mesma;

27 – A fórmula da Coluna I – Horas Normais – passará a ser:

=SE(B8=””;””;SE(OU(CONT.SE(fer;B8)>0;DIA.DA.SEMANA(B8)=1);0;SE(DIA.DA.SEMANA(B8)=7;MÍNIMO($H$3;H8);MÍNIMO($H$2;H8))))

28 – Se a função OU() retornar VERDADEIRO, a data em B8 ou é um feriado ou é um domingo e, portanto, zero é retornado. Do contrário, o Excel calcula a jornada normal correspondente ao sábado ou aos demais dias úteis.

29 – O passo seguinte é alterar a fórmula da coluna J – Horas Extras – de modo que nessa coluna sejam apuradas somente as horas extras laboradas em dias úteis de segunda a sábado.

=SE(B8=””;””;SE(I8=0;0;SE(DIA.DA.SEMANA(B8)=7;MÁXIMO(0;H8-$H$3);MÁXIMO(0;H8-$H$2))))

30 – Se I8 é igual a zero, a data em B8 ou é um feriado ou é um domingo e, sendo assim, zero é retornado, pois esta coluna irá apurar somente as horas extras laboradas em dias úteis.

31 – Para o cálculo das horas trabalhadas em domingos e feriados vamos utilizar a coluna K. Nesta coluna, temos que inserir uma fórmula que considere todas as horas trabalhadas em domingos e feriados como horas extras. A fórmula desta coluna é simples:

=SE(B8=””;””;SE(I8=0;H8;0))

32 – Se o valor em I8 é igual a zero, o valor da coluna H (Horas Trab.) é inserido na coluna K (Dom e Fer), do contrário, zero é retornado.

33 – Feitas todas as alterações na linha 8, devemos copiar as novas fórmulas para as células que estão abaixo até a linha 38.

planilha

34 – Com isso está finalizada a versão 2 da planilha de controle de ponto. No próximo tutorial, introduziremos uma coluna para apuração do adicional noturno.

35 – Caso ainda tenha dúvidas, por favor, deixe seu comentário.

Para saber mais sobre os feriados nacionais e municipais  acesse aqui

Deixe um comentário

O seu endereço de e-mail não será publicado. Campos obrigatórios são marcados com *